Newsletter ed allegati

Come inviare facilmente una newsletter agli utenti del vostro sito con file in allegato... Utilizzeremo i file di testo e le funzioni CDONTS di ASP.
Gli elementi a nostra disposizione sono:

1. un file di testo lista.txt al cui interno saranno contenuti gli indirizzi di posta elettronica e le password dei vostri iscritti (durante la fase di iscrizione è proprio all'interno di questo file che gli utenti verranno memorizzati).
2. Una pagina HTML da inviare agli utenti msg_16042003.htm Attenzione tutti i collegamenti alle immagini ed agli sfondi devono essere di tipo assoluto.
3. Un'immagine da allegare al messaggio
immagine.gif.
4. Un documento ASP che legge le email contenute in lista.txt e che invia il messaggio e che allega un'immagine un file zippato della lezione della settimana.

Quando i primi due elementi sono pronti, procediamo creare il file mailing.asp

Iniziamo con l'apertura del documento HTML da inviare ai partecipanti della lista, l'intero documento viene salvato all'interno della variabile "testo" quindi il documento viene chiuso.

<%
dim EMail, lista, utente, lista_utenti, allegato
dim FSO, documentoHTML, inFile
'Creazione dell'istanza FileSystem
Set FSO = CreateObject("Scripting.FileSystemObject")
' [1] lettura, [2] scrittura, [8] appendi
documentoHTML=Server.MapPath("msg_16042003.html")
Set inFile=FSO.OpenTextFile(documentoHTML,1,False,0)
do while not inFile.AtEndOfStream
testo=testo & inFile.ReadLine() & vbCrLf
loop
inFile.Close
Set inFile= Nothing

La fase successiva è quella di aprire il file "lista.txt" e memorizzare gli indirizzi all'interno della variabile "utente".
Utilizzando ancora il File System Object individuamo anche l'allegato da inviare...

lista_utenti=Server.MapPath("lista.txt")
Set inFile=FSO.OpenTextFile(lista_utenti,1,False,0)
do while not inFile.AtEndOfStream
utente= utente & inFile.ReadLine() & ";"
loop
inFile.Close
Set inFile= Nothing
allegato=Server.MapPath("immagine.gif")
Set FSO = Nothing

La fase finale invia il messaggio di posta con l'allegato. Da osservare come il messaggio viene inviato ai destinatari attraverso il bcc, Blind Carbon Copy (copia carbone nascosta) in modo che le persone che ricevono il messaggio non vedano gli indirizzi degli altri, per ovvi motivi di sicurezza e di privacy.

Set EMail= CreateObject("CDONTS.NewMail")
EMail.Subject="[gg.mm.yyyy] News dal nome_tuo_sito "
EMail.BodyFormat=0
EMail.MailFormat=0
EMail.Body=testo
' e' il testo estrapolato dalla pagina HTML
EMail.From="mail@tuosito.it"
EMail.bcc=utente
'sono gli utenti estratti dal file lista.txt
EMail.AttachFile allegato
EMail.Send
Set EMail=Nothing
response.write("Messaggi inviati correttamente!!")
%>

La nostra newsletter è quindi pronta e perfettamente funzionante... alla prossima puntata.